본문으로 건너뛰기
토파즈문서

문서 검색

명세 6.0

방향키로 결과를 고르고 Enter를 눌러 여세요.

API 이름, 진단 번호, 규칙 또는 프로젝트 주제를 입력하세요.

    다운로드 →

    설계 결정

    식, 패턴, 제어 흐름

    양의 값은 단항 더하기 없이 씁니다

    2026년 11월 7일 채택 · 6.0.0 · 확인 중

    문제

    양의 수나 이미 얻은 값에 앞쪽 +를 붙일 수 있었습니다. 붙이거나 빼도 값은 그대로였습니다.

    결정

    단항 +를 없앱니다. 피연산자를 그대로 씁니다.

    예제

    Rejecting unary plus before an integer

    example.tpzRejecting unary plus before an integer플레이그라운드 열기 →
    1. let value = +1
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    Rejecting unary plus before a bound value

    example.tpzRejecting unary plus before a bound value플레이그라운드 열기 →
    1. let value = 1
    2. let copy = +value
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    Rejecting unary plus before a float

    example.tpzRejecting unary plus before a float플레이그라운드 열기 →
    1. let value = +1.5
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    Using ordinary values, negation, and binary addition

    example.tpzUsing ordinary values, negation, and binary addition플레이그라운드 열기 →
    1. import std.io
    2. let value = 3
    3. io.writeLine("{1}")
    4. io.writeLine("{1.5}")
    5. io.writeLine("{value}")
    6. io.writeLine("{-value}")
    7. io.writeLine("{value + 2}")
    기대 출력종료 코드 0
    1
    1.5
    3
    -3
    5
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 1
    2. 1.5
    3. 3
    4. -3
    5. 5

    검토한 대안

    • 단항 +를 유지한다. 같은 값을 두 가지 철자로 쓰게 됩니다.

    이유

    값을 바꾸는 단항 연산만 따로 읽으면 됩니다.

    바뀐 규칙 Unary operators →

    배열과 집합과 범위의 원소 포함은 in으로 씁니다

    2026년 11월 7일 채택 · 6.0.0 · 구현 중

    문제

    컬렉션에 값이 들어 있는지 확인할 때 연산자와 메서드가 같은 검사를 맡을 수 있었습니다. 문자열의 부분 포함이나 맵의 키 조회는 뜻이 다릅니다.

    결정

    • 배열, 집합, 범위에 원소가 있는지는 in으로 확인합니다. Set.contains는 쓰지 않습니다.
    • 문자열의 부분 포함과 맵의 키 조회는 각각의 연산을 씁니다.

    예제

    Use in for arrays, sets, and ranges

    example.tpzUse in for arrays, sets, and ranges플레이그라운드 열기 →
    1. import std.io
    2. let values = [1, 3]
    3. let members = set { 1, 3 }
    4. let odds = 1..<5 by 2
    5. io.writeLine("{1 in values}:{2 in values}")
    6. io.writeLine("{1 in members}:{2 in members}")
    7. io.writeLine("{1 in odds}:{2 in odds}")
    기대 출력종료 코드 0
    true:false
    true:false
    true:false
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. true:false
    2. true:false
    3. true:false

    A Map is not an element-membership container

    example.tpzA Map is not an element-membership container플레이그라운드 열기 →
    1. let found = "key" in map { "key": 1 }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    필수 기본 위치 계약은 미정입니다.

    Substring search is not element membership

    example.tpzSubstring search is not element membership플레이그라운드 열기 →
    1. let found = "a" in "abc"
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    필수 기본 위치 계약은 미정입니다.

    검토한 대안

    • contains와 in을 모두 둔다. 같은 원소 포함 검사에 표기가 둘 남습니다.

    이유

    원소를 찾는 검사인지, 부분 문자열이나 키를 찾는 검사인지 호출에서 드러납니다.

    바뀐 규칙 Comparison and membership →

    값이 없으면 선택적 메서드 호출의 인수도 건너뜁니다

    2026년 11월 18일 채택 · 6.0.0 · 확인 중

    문제

    선택적 호출이 값 없이 끝날 때 인수에서 출력이나 실패가 일어나면 호출 생략의 뜻이 달라집니다. 사용자 메서드와 내장 메서드에 같은 규칙이 필요합니다.

    결정

    • 받는 값을 한 번 평가합니다. None()이나 null이면 멤버 조회와 인수, 펼침, 콜백 생성식, 생략한 기본값을 모두 건너뛰고 같은 빈 값을 돌려줍니다.
    • 값이 있으면 안의 값에서 메서드를 찾아 일반 호출 순서로 실행합니다.
    • 정적 서명과 인수 검사는 값이 있는지와 무관합니다.
    • Option의 반환값은 겹쳐 감싸지 않습니다. null을 허용하는 호출은 null을 그대로 구별합니다.
    • 내장 메서드를 값으로 떼어 내는 것은 읽기 메서드에만 허용합니다. 변경 메서드를 떼어 내면 거절합니다.

    예제

    Option receiver, present

    example.tpzOption receiver, present
    1. record P { x: int }
    2. impl P {
    3. function plus(self, n: int) -> int { self.x + n }
    4. function next(self) -> Option<int> { Some(self.x + 1) }
    5. }
    6. let p: Option<P> = Some(P { x: 1 })
    7. let result: Option<int> = p?.plus(2)
    기대 출력종료 코드 0
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    검사가 프로그램을 받아들입니다. 종료 코드 0.

    Option receiver, absent

    example.tpzOption receiver, absent
    1. record P { x: int }
    2. impl P {
    3. function plus(self, n: int) -> int { self.x + n }
    4. function next(self) -> Option<int> { Some(self.x + 1) }
    5. }
    6. let p: Option<P> = None()
    7. let result: Option<int> = p?.plus(2)
    기대 출력종료 코드 0
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    검사가 프로그램을 받아들입니다. 종료 코드 0.

    Option result stays one layer

    example.tpzOption result stays one layer
    1. record P { x: int }
    2. impl P {
    3. function plus(self, n: int) -> int { self.x + n }
    4. function next(self) -> Option<int> { Some(self.x + 1) }
    5. }
    6. let p: Option<P> = Some(P { x: 1 })
    7. let result: Option<int> = p?.next()
    기대 출력종료 코드 0
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    검사가 프로그램을 받아들입니다. 종료 코드 0.

    Nullable receiver, present

    example.tpzNullable receiver, present
    1. record P { x: int }
    2. impl P {
    3. function plus(self, n: int) -> int { self.x + n }
    4. function next(self) -> Option<int> { Some(self.x + 1) }
    5. }
    6. let p: P | null = P { x: 1 }
    7. let result: int | null = p?.plus(2)
    기대 출력종료 코드 0
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    검사가 프로그램을 받아들입니다. 종료 코드 0.

    Nullable receiver, absent

    example.tpzNullable receiver, absent
    1. record P { x: int }
    2. impl P {
    3. function plus(self, n: int) -> int { self.x + n }
    4. function next(self) -> Option<int> { Some(self.x + 1) }
    5. }
    6. let p: P | null = null
    7. let result: int | null = p?.plus(2)
    기대 출력종료 코드 0
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    검사가 프로그램을 받아들입니다. 종료 코드 0.

    Nullable receiver with Option return

    example.tpzNullable receiver with Option return
    1. record P { x: int }
    2. impl P {
    3. function plus(self, n: int) -> int { self.x + n }
    4. function next(self) -> Option<int> { Some(self.x + 1) }
    5. }
    6. let p: P | null = P { x: 1 }
    7. let result: Option<int> | null = p?.next()
    기대 출력종료 코드 0
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    검사가 프로그램을 받아들입니다. 종료 코드 0.

    Absent receiver still checks member

    example.tpzAbsent receiver still checks member플레이그라운드 열기 →
    1. record P { x: int }
    2. impl P {
    3. function plus(self, n: int) -> int { self.x + n }
    4. function next(self) -> Option<int> { Some(self.x + 1) }
    5. }
    6. let p: Option<P> = None()
    7. let result = p?.missing(1)
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    필수 기본 위치 계약은 미정입니다.

    Absent receiver skips argument expression

    example.tpzAbsent receiver skips argument expression
    1. import std.io
    2. record P { x: int }
    3. impl P { function plus(self, n: int) -> int { self.x + n } }
    4. function argument() -> int {
    5. io.writeLine("arg")
    6. 2
    7. }
    8. let p: Option<P> = None()
    9. let result = p?.plus(argument())
    10. io.writeLine("done")
    기대 출력종료 코드 0
    done
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. done

    Optional union checks every arm

    example.tpzOptional union checks every arm
    1. record A { x: int }
    2. record B { x: int }
    3. impl A { function plus(self, n: int) -> int { self.x + n } }
    4. impl B { function plus(self, n: string) -> int { self.x } }
    5. let value: (A | B) | null = null
    6. let result = value?.plus(2)
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    필수 기본 위치 계약은 미정입니다.

    검토한 대안

    • 사용자 메서드만 ?.를 막는 지금 동작을 둔다. 내장 메서드와 사용자 메서드의 호출 규칙이 갈리고 같은 뜻을 if let이나 match로 길게 써야 합니다.
    • 내장 메서드에도 ?.를 막는다. 명세는 이미 선택적 접근을 일반 멤버 규칙으로 둡니다.

    이유

    어떤 경우에 인수가 실행되는지 메서드의 종류와 관계없이 예측할 수 있습니다.

    바뀐 규칙 Member, index, and optional access →

    데이터 흐름을 일반 호출과 바인딩으로 씁니다

    2026년 11월 7일 채택 · 6.0.0 · 확인 중

    문제

    값을 함수에 넘길 때 일반 호출과 파이프 표기를 모두 쓸 수 있었습니다. 중간 값을 다시 쓰거나 효과의 순서를 드러내려면 다른 규칙도 필요했습니다.

    결정

    • |>, >>와 식 자리에 쓰는 _를 없앱니다. 일반 호출과 함수로 이어 씁니다.
    • 효과 순서나 중간 값의 재사용은 let으로 적습니다.

    예제

    Reject a pipeline placeholder

    example.tpzReject a pipeline placeholder플레이그라운드 열기 →
    1. function subtract(a: int, b: int) -> int { a - b }
    2. let value = 3 |> subtract(10, _)
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    필수 기본 위치 계약은 미정입니다.

    Reject the composition operator

    example.tpzReject the composition operator플레이그라운드 열기 →
    1. function increment(n: int) -> int { n + 1 }
    2. function double(n: int) -> int { n * 2 }
    3. let composed = increment >> double
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    필수 기본 위치 계약은 미정입니다.

    Reject a standalone expression placeholder

    example.tpzReject a standalone expression placeholder플레이그라운드 열기 →
    1. let value = _
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    필수 기본 위치 계약은 미정입니다.

    Save values to preserve call and composition effects

    example.tpzSave values to preserve call and composition effects플레이그라운드 열기 →
    1. import std.io
    2. function input() -> int {
    3. io.writeLine("input")
    4. 3
    5. }
    6. function subtract(a: int, b: int) -> int { a - b }
    7. function stage() -> (int, int) -> int {
    8. io.writeLine("callee")
    9. subtract
    10. }
    11. function argument() -> int {
    12. io.writeLine("argument")
    13. 10
    14. }
    15. let saved = input()
    16. let callee = stage()
    17. let written = argument()
    18. io.writeLine("{callee(written, saved)}")
    19. function increment(n: int) -> int { n + 1 }
    20. function double(n: int) -> int { n * 2 }
    21. function first() -> (int) -> int {
    22. io.writeLine("first")
    23. increment
    24. }
    25. function second() -> (int) -> int {
    26. io.writeLine("second")
    27. double
    28. }
    29. let left = first()
    30. let right = second()
    31. let composed = (n: int) => right(left(n))
    32. io.writeLine("{composed(3)}:{composed(5)}")
    기대 출력종료 코드 0
    input
    callee
    argument
    7
    first
    second
    8:12
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. input
    2. callee
    3. argument
    4. 7
    5. first
    6. second
    7. 8:12

    검토한 대안

    • 파이프나 합성 연산의 일부를 남긴다. 같은 호출을 표현하는 일반 호출과 별도 연산자 문법이 계속 겹칩니다.
    • 연산자를 모두 그대로 둔다. 같은 호출을 쓰는 방법이 하나여야 합니다.

    이유

    호출과 바인딩에서 값이 어디로 가고 언제 평가되는지 읽을 수 있습니다.

    바뀐 규칙 Ordinary calls and saved values →Compose calls in a function body →

    제어문에 들어가는 식은 괄호로 감쌉니다

    2026년 11월 7일 채택 · 6.0.0 · 확인 중

    문제

    제어문 머리에 레코드나 람다가 오면 어느 부분까지가 입력 식인지 구분해야 합니다. 머리에서만 다른 식 문법을 쓰면 같은 식을 옮기기 어렵습니다.

    결정

    • if (test), match (value), while (test)처럼 제어 입력과 조건을 괄호로 감쌉니다.
    • 범위 패턴도 (low .. high)로 씁니다. 괄호 안에는 일반 식 문법을 씁니다.

    예제

    Reject an undelimited if operand

    example.tpzReject an undelimited if operand플레이그라운드 열기 →
    1. let value = if true { 1 } else { 0 }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    • TPZ2001 →

      control-operand-parentheses at example.tpz:1:16

    Record construction and update use ordinary operand grammar

    example.tpzRecord construction and update use ordinary operand grammar플레이그라운드 열기 →
    1. import std.io
    2. record Flag { enabled: bool }
    3. let state = { enabled: true }
    4. let first = if (Flag { enabled: true }.enabled) { 1 } else { 0 }
    5. let second = if (state { enabled: false }.enabled) { 1 } else { 2 }
    6. let third = match (Flag { enabled: true }) {
    7. case Flag { enabled: true } => true
    8. case _ => false
    9. }
    10. io.writeLine("{first},{second},{third}")
    기대 출력종료 코드 0
    1,2,true
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 1,2,true

    Reject an unwrapped range pattern

    example.tpzReject an unwrapped range pattern플레이그라운드 열기 →
    1. let value = match (2) {
    2. case 1 .. 3 => 1
    3. case _ => 0
    4. }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    • TPZ2001 →

      range-pattern-parentheses at example.tpz:2:10

    A delimited range precedes a lambda-valued arm

    example.tpzA delimited range precedes a lambda-valued arm플레이그라운드 열기 →
    1. import std.io
    2. let low = 1
    3. let high = 3
    4. let chosen = match (2) {
    5. case (low .. high) => (value: int) => value + 1
    6. case _ => (value: int) => value
    7. }
    8. io.writeLine("{chosen(6)}")
    기대 출력종료 코드 0
    7
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 7

    검토한 대안

    • 제어문 머리만의 문법을 유지한다. 함수 본문이나 대입에서 쓰던 식에도 머리에서만 다른 규칙이 생깁니다.
    • 레코드와 람다 축약 쪽의 문법을 바꾼다. 문맥마다 다른 식 문법이 남습니다.

    이유

    입력 범위가 눈에 보이고, 같은 식을 여러 자리에서 같은 문법으로 쓸 수 있습니다.

    바뀐 규칙 Explicit control operands →Range pattern boundaries →

    피연산자는 왼쪽부터 평가합니다

    2026년 11월 9일 채택 · 6.0.0 · 확인 중

    문제

    두 피연산자가 출력하거나 실패할 수 있으면 먼저 계산하는 쪽이 결과를 바꿉니다. 평가 순서가 정해져 있어야 어떤 오류가 나올지 알 수 있습니다.

    결정

    • 이항식과 그 안의 피연산자를 왼쪽에서 오른쪽으로 평가합니다. 먼저 발생한 실행 오류를 보고합니다.
    • 단락 연산은 필요한 피연산자만 평가합니다. 호출 인수와 컬렉션 및 레코드 요소는 소스 순서를 따릅니다.

    예제

    Binary and nested operands print from left to right

    example.tpzBinary and nested operands print from left to right플레이그라운드 열기 →
    1. import std.io
    2. function value(label: string, number: int) -> int {
    3. io.writeLine(label)
    4. number
    5. }
    6. let result = value("left", 1) + value("middle", 2) * value("right", 3)
    7. io.writeLine("{result}")
    기대 출력종료 코드 0
    left
    middle
    right
    7
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. left
    2. middle
    3. right
    4. 7

    The left operand faults before the right operand runs

    example.tpzThe left operand faults before the right operand runs플레이그라운드 열기 →
    1. import std.io
    2. function left(divisor: int) -> int {
    3. io.writeLine("left")
    4. 1 / divisor
    5. }
    6. function right(number: int) -> int {
    7. io.writeLine("right")
    8. 9223372036854775807 + number
    9. }
    10. left(0) + right(1)
    기대 출력0이 아닌 종료 코드
    left
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 run. 종료 코드가 0이 아닙니다.

    기대 표준 출력
    1. left

    검토한 대안

    • 평가 순서를 미정으로 둔다. 같은 프로그램에서 출력이나 먼저 보이는 오류가 달라질 수 있습니다.

    이유

    소스 순서로 출력과 오류를 예측할 수 있습니다.

    바뀐 규칙 Operand and assignment evaluation order →

    해결한 미정 항목 Pending: remaining evaluation-order guarantees →

    쓰기 대상은 우변과 인수를 평가한 뒤 정합니다

    2026년 11월 16일 채택 · 6.0.0 · 확인 중

    문제

    색인 대입의 우변이나 변경 메서드의 인수가 수신 값을 다시 대입할 수 있습니다. 어느 값이 쓰기를 받느냐에 따라 결과가 달라집니다.

    결정

    • 색인 대입과 변경 메서드는 우변이나 인수의 평가를 끝낸 뒤 현재 바인딩의 값에 씁니다.
    • 쓰기 바로 앞에서 칸을 다시 검사합니다. xs[0] = shrink()에서 shrink가 xs = [7]을 실행한 뒤 5를 반환하면 최종 값은 [5]입니다.

    예제

    A write uses the receiver after the arguments rebind it

    main.tpzA write uses the receiver after the arguments rebind it플레이그라운드 열기 →
    1. import std.io
    2. let mut xs = [1, 2]
    3. function shrink() -> int {
    4. xs = [7]
    5. 5
    6. }
    7. xs[0] = shrink()
    8. io.writeLine("{xs}")
    9. let mut ys = [3]
    10. function reset() -> int {
    11. ys = [0]
    12. 4
    13. }
    14. ys.push(reset())
    15. io.writeLine("{ys}")
    기대 출력종료 코드 0
    [5]
    [0, 4]
    
    $ topaz run main.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. [5]
    2. [0, 4]

    검토한 대안

    • 평가를 시작할 때 가리킨 값에 쓴다. 바인딩이 이미 새 값을 가리키므로 버려진 옛 값에 쓰게 됩니다.

    이유

    부수 효과로 바인딩이 바뀌어도 쓰기의 마지막 단계에 어떤 값을 수정할지 알 수 있습니다.

    바뀐 규칙 Operand and assignment evaluation order →

    숫자 패턴은 음수 리터럴도 받습니다

    2026년 11월 18일 채택 · 6.0.0 · 확인 중

    문제

    양수를 직접 비교하면서 음수만 범위나 조건으로 표현해야 하면 같은 분기가 다른 모양이 됩니다. 부호가 붙은 0을 어떻게 비교하는지도 맞춰야 합니다.

    결정

    • 숫자 리터럴 패턴 앞에는 단항 - 하나를 붙일 수 있습니다. -x처럼 이름을 쓰거나 독립 패턴을 괄호로 감싸는 형태는 받지 않습니다.
    • 패턴 값과 진단은 같은 철자의 식과 같습니다. 일치는 숫자 동등성을 따르므로 -0.0과 0.0은 같습니다.
    • 조건 없는 0 갈래 뒤에 같은 종류의 음의 0 갈래를 쓰면 검사 단계의 TPZ5713입니다.

    예제

    Negative numeric literal patterns preserve expression values

    example.tpzNegative numeric literal patterns preserve expression values
    1. import std.io
    2. function integer(value: int) -> int {
    3. match (value) {
    4. case -1 => 1
    5. case -0x8000000000000000 => 2
    6. case -1_000 => 3
    7. case -0 => 4
    8. case _ => 0
    9. }
    10. }
    11. function floating(value: float) -> int {
    12. match (value) {
    13. case -1.5 => 5
    14. case -0.0 => 6
    15. case _ => 0
    16. }
    17. }
    18. io.writeLine("{integer(-1)}")
    19. io.writeLine("{integer(-9223372036854775808)}")
    20. io.writeLine("{integer(-1000)}")
    21. io.writeLine("{integer(0)}")
    22. io.writeLine("{floating(-1.5)}")
    23. io.writeLine("{floating(0.0)}")
    기대 출력종료 코드 0
    1
    2
    3
    4
    5
    6
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 1
    2. 2
    3. 3
    4. 4
    5. 5
    6. 6

    An earlier float zero case covers negative float zero

    example.tpzAn earlier float zero case covers negative float zero
    1. function classify(value: float) -> int {
    2. match (value) {
    3. case 0.0 => 1
    4. case -0.0 => 2
    5. case _ => 0
    6. }
    7. }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    An earlier zero case covers negative zero

    example.tpzAn earlier zero case covers negative zero
    1. function classify(value: int) -> int {
    2. match (value) {
    3. case 0 => 1
    4. case -0 => 2
    5. case _ => 0
    6. }
    7. }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    A standalone grouped negative literal pattern is rejected

    example.tpzA standalone grouped negative literal pattern is rejected플레이그라운드 열기 →
    1. function classify(value: int) -> int {
    2. match (value) {
    3. case (-1) => 1
    4. case _ => 0
    5. }
    6. }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    필수 기본 위치 계약은 미정입니다.

    A repeated minus does not form a literal pattern

    example.tpzA repeated minus does not form a literal pattern플레이그라운드 열기 →
    1. function classify(value: int) -> int {
    2. match (value) {
    3. case --1 => 1
    4. case _ => 0
    5. }
    6. }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    필수 기본 위치 계약은 미정입니다.

    검토한 대안

    • 음수는 범위나 조건으로만 표현하게 한다. 같은 값을 양수일 때와 음수일 때 다르게 적게 됩니다.
    • 부호가 다른 0을 비트로 비교한다. 패턴 비교와 ==의 결과가 갈립니다.

    이유

    숫자 하나를 비교하는 방법은 부호와 상관없이 같습니다.

    바뀐 규칙 Pattern forms and name interpretation →

    레코드 패턴은 필드 이름과 하위 패턴을 함께 씁니다

    2026년 11월 7일 채택 · 6.0.0 · 확인 중

    문제

    레코드를 분해할 때 필드 이름과 새로 붙일 이름이 같을 수 있습니다. 이름만 적으면 필드 이름을 쓴 건지 값을 바인딩한 건지 한눈에 드러나지 않습니다.

    결정

    레코드 패턴의 각 필드는 field: pattern으로 씁니다.

    예제

    Rejecting a structural field shorthand

    example.tpzRejecting a structural field shorthand플레이그라운드 열기 →
    1. let { value } = { value: 1 }
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    • TPZ2001 →

      record-pattern-field-colon at example.tpz:1:13

    Rejecting a nominal field shorthand

    example.tpzRejecting a nominal field shorthand플레이그라운드 열기 →
    1. record Point { x: int }
    2. let Point { x } = Point { x: 1 }
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    • TPZ2001 →

      record-pattern-field-colon at example.tpz:2:15

    Binding and renaming fields explicitly

    example.tpzBinding and renaming fields explicitly플레이그라운드 열기 →
    1. import std.io
    2. record Point { x: int, y: int }
    3. let { value: value } = { value: 7 }
    4. let Point { x: first, y: second } = Point { x: 2, y: 3 }
    5. io.writeLine("{value} {first} {second}")
    기대 출력종료 코드 0
    7 2 3
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 7 2 3

    검토한 대안

    • 필드 이름만 쓰는 축약에 일부 예외를 두어 허용한다. 같은 바인딩에 두 형태와 축약 전용 규칙이 생깁니다.

    이유

    필드를 읽는 곳과 값에 이름을 붙이는 곳이 코드에서 분명합니다.

    바뀐 규칙 Pattern forms and name interpretation →

    레코드 패턴에서 빠진 콜론은 구문 오류입니다

    2026년 11월 7일 채택 · 6.0.0 · 확인 중

    문제

    필드와 하위 패턴 사이의 콜론을 빼면 파서가 이미 그 코드를 거절합니다. 같은 입력에 검사 단계의 별도 오류를 정의할 필요가 있는지 살폈습니다.

    결정

    TPZ5611은 내부 방어용으로 예약합니다. 빠진 콜론은 구문 분석 단계의 TPZ2001입니다.

    예제

    Rejecting a structural field shorthand →

    Rejecting a nominal field shorthand →

    검토한 대안

    • 검사 단계에 도달하는 별도 TPZ5611 조건을 만든다. 구문 분석에서 이미 거절하는 입력에 다른 사용 규칙이 생깁니다.

    이유

    필드의 표기 오류가 소스를 읽는 단계에서 드러납니다.

    바뀐 규칙 Pattern forms and name interpretation →

    갈래에서 함수의 값을 돌려줄 때 블록을 씁니다

    2026년 11월 7일 채택 · 6.0.0 · 확인 중

    문제

    match의 갈래는 결과 식을 받지만 함수에서 바로 돌아가야 할 때도 있습니다. 그 자리에 return을 바로 쓰면 식과 문장의 경계가 달라집니다.

    결정

    갈래에서 return을 쓸 때는 블록 안에 넣습니다.

    예제

    Rejecting a return without an arm block

    example.tpzRejecting a return without an arm block플레이그라운드 열기 →
    1. function choose(flag: bool) -> int {
    2. while (true) {
    3. let value = match (flag) {
    4. case true => return 7
    5. case false => 3
    6. }
    7. return value
    8. }
    9. 0
    10. }
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    • TPZ2001 →

      match-arm-return-needs-block at example.tpz:4:26

    Returning through a match arm block

    example.tpzReturning through a match arm block플레이그라운드 열기 →
    1. import std.io
    2. function choose(flag: bool) -> int {
    3. while (true) {
    4. let value = match (flag) {
    5. case true => { return 7 }
    6. case false => 3
    7. }
    8. return value
    9. }
    10. 0
    11. }
    12. io.writeLine("{choose(true)}")
    13. io.writeLine("{choose(false)}")
    기대 출력종료 코드 0
    7
    3
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 7
    2. 3

    검토한 대안

    • 갈래에서만 return을 식처럼 직접 쓸 수 있게 둔다. 같은 반환문에 match만의 예외가 생깁니다.
    • 모든 식 자리에서 return 식을 허용한다. return이 문장으로만 쓰이는 규칙 하나를 지켜야 합니다.

    이유

    블록 안에서 반환문은 다른 자리와 같은 문법을 따릅니다.

    바뀐 규칙 Case selection and guards →

    먼저 맞는 갈래를 고르고 가려진 갈래는 거절합니다

    2026년 11월 8일 채택 · 6.0.0 · 구현 중 · 판 2

    문제

    특별한 값을 먼저 처리하고 나머지에는 일반 규칙을 적용할 수 있습니다. 두 패턴이 겹친다는 이유만으로 거절하면 조건식이나 구조 변경이 필요합니다.

    결정

    • match는 소스 순서로 시험하고 패턴과 조건이 처음으로 함께 맞는 갈래를 고릅니다.
    • 뒤의 일반 패턴이 앞의 특별한 패턴과 겹칠 수 있습니다.
    • 앞선 조건 없는 갈래들이 한 갈래의 모든 값을 덮으면 검사 단계에서 거절합니다.

    예제

    A repeated unguarded literal case is unreachable

    example.tpzA repeated unguarded literal case is unreachable
    1. function choose(value: int) -> int {
    2. match (value) {
    3. case 1 => 10
    4. case 1 => 20
    5. case _ => 0
    6. }
    7. }
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    Overlapping guarded cases follow source order

    example.tpzOverlapping guarded cases follow source order플레이그라운드 열기 →
    1. import std.io
    2. function choose(value: int) -> string {
    3. match (value) {
    4. case number if (number > 0) => "positive"
    5. case number if (number <= 0) => "nonpositive"
    6. case _ => "other"
    7. }
    8. }
    9. io.writeLine(choose(4))
    10. io.writeLine(choose(0))
    기대 출력종료 코드 0
    positive
    nonpositive
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. positive
    2. nonpositive

    A later wildcard is covered by two earlier unguarded cases

    example.tpzA later wildcard is covered by two earlier unguarded cases
    1. let value: bool = true
    2. let result = match (value) {
    3. case true => "yes"
    4. case false => "no"
    5. case _ => "hidden"
    6. }
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    Cover all payloads of a constructor with two bool fields

    example.tpzCover all payloads of a constructor with two bool fields
    1. enum E { Pair(bool, bool), Empty }
    2. function f(e: E) -> int { match (e) { case Pair(_, true) => 1
    3. case Pair(_, false) => 2
    4. case Empty() => 3 } }
    기대 출력종료 코드 0
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    검사가 프로그램을 받아들입니다. 종료 코드 0.

    검토한 대안

    • 갈래 순서와 무관하게 겹침을 거절한다. 특별한 경우를 먼저 써서 예외임을 드러낼 수 없습니다.

    이유

    특별한 경우를 먼저 둘 수 있고, 앞에서 이미 다 처리한 갈래는 검사 때 드러납니다.

    바뀐 규칙 Case selection and guards →Reachable overlapping cases →

    판 이력
    • 판 1 · 2026년 11월 7일 채택 · 첫 결정은 확실히 분리되는 패턴만 함께 허용했습니다

      대칭적인 교집합 검사와 단일 대체 팔을 처음 채택했습니다.

    리터럴로 쓴 빈 범위 패턴은 검사에서 거절합니다

    2026년 11월 18일 채택 · 6.0.0 · 확인 중

    문제

    ..와 ..<를 헷갈리면 어떤 값도 받지 않는 범위가 됩니다. 주변 갈래는 여전히 실행될 수 있어 그 자리의 실수를 놓치기 쉽습니다.

    결정

    • 두 끝값이 정수 리터럴인 패턴은 먼저 일반 리터럴 검사를 합니다.
    • (a ..< b)에서 a >= b이거나 (a .. b)에서 a > b면 검사 단계의 TPZ5714입니다. 괄호로 감싼 리터럴과 중첩 패턴도 같습니다.
    • 계산한 끝값의 범위는 실행 중 비면 일치하지 않습니다.

    예제

    An exclusive literal range with equal endpoints is rejected

    example.tpzAn exclusive literal range with equal endpoints is rejected
    1. function classify(value: int) -> int {
    2. match (value) {
    3. case (0 ..< 0) => 1
    4. case _ => 0
    5. }
    6. }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    A reversed inclusive literal range is rejected

    example.tpzA reversed inclusive literal range is rejected
    1. function classify(value: int) -> int {
    2. match (value) {
    3. case (5 .. 1) => 1
    4. case _ => 0
    5. }
    6. }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    An empty range is rejected inside a reachable alternative

    example.tpzAn empty range is rejected inside a reachable alternative
    1. function classify(value: int) -> int {
    2. match (value) {
    3. case (0 ..< 0) | 1 => 1
    4. case _ => 0
    5. }
    6. }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    A for pattern rejects a static empty range

    example.tpzA for pattern rejects a static empty range
    1. for (0 ..< 0) in ([0]) {
    2. }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    A computed empty range fails to match at runtime

    example.tpzA computed empty range fails to match at runtime플레이그라운드 열기 →
    1. import std.io
    2. function endpoint(value: int) -> int { value }
    3. let result = match (0) {
    4. case (endpoint(0) ..< endpoint(0)) => 1
    5. case _ => 2
    6. }
    7. io.writeLine("{result}")
    기대 출력종료 코드 0
    2
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 2

    검토한 대안

    • 앞선 갈래가 덮는 오류인 TPZ5713을 재사용한다. 빈 범위 자체가 문제여도 진단이 앞선 갈래를 탓하게 됩니다.
    • 빈 리터럴 범위를 그냥 일치하지 않게 둔다. 경계를 잘못 쓴 갈래가 조용히 죽은 코드가 될 수 있습니다.

    이유

    다른 갈래나 주위를 바꾸지 않고 잘못된 범위를 바로 찾을 수 있습니다.

    바뀐 규칙 Integer range patterns →

    계산한 끝값은 범위 패턴을 시험할 때마다 평가합니다

    2026년 11월 17일 채택 · 6.0.0 · 확인 중

    문제

    패턴의 뒤쪽 대안에 실패할 수 있는 함수가 있어도 앞의 대안이 이미 맞을 수 있습니다. 끝값을 미리 평가하면 건너뛸 자리에서 프로그램이 멈춥니다.

    결정

    • 범위에 닿으면 계산한 아래 끝값을 평가한 뒤 위 끝값을 평가합니다. 다음 시험에서는 다시 계산합니다.
    • 바깥 패턴이 먼저이며 대안은 왼쪽부터 시험합니다. 첫 성공 대안까지 계산하고, 갈래의 조건이 거짓이면 다음 갈래를 시험합니다.
    • match, for, 구조 분해에 이 순서를 씁니다. 실제로 평가한 끝값의 실패와 ?는 자리의 원래 제어 규칙을 따릅니다.

    예제

    A successful range alternative skips later endpoints

    example.tpzA successful range alternative skips later endpoints
    1. import std.io
    2. function bound(value: int) -> int { value }
    3. function boom(divisor: int) -> int { 1 / divisor }
    4. let chosen = match (0) {
    5. case (0 .. bound(1)) | (0 .. boom(0)) => 7
    6. case _ => 9
    7. }
    8. io.writeLine("{chosen}")
    기대 출력종료 코드 0
    7
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 7

    A false guard continues with the next case

    example.tpzA false guard continues with the next case
    1. import std.io
    2. function end(label: string) -> int {
    3. io.writeLine(label)
    4. 1
    5. }
    6. let chosen = match (0) {
    7. case (0 .. 1) | (0 .. end("or")) if (false) => 1
    8. case (0 .. end("next")) => 2
    9. case _ => 9
    10. }
    11. io.writeLine("{chosen}")
    기대 출력종료 코드 0
    next
    2
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. next
    2. 2

    A for pattern evaluates endpoints for each element

    example.tpzA for pattern evaluates endpoints for each element
    1. import std.io
    2. function high() -> int {
    3. io.writeLine("high")
    4. 1
    5. }
    6. for (0 .. high()) in ([1, 1]) {
    7. io.writeLine("matched")
    8. }
    기대 출력종료 코드 0
    high
    matched
    high
    matched
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. high
    2. matched
    3. high
    4. matched

    A reached endpoint failure stops matching

    example.tpzA reached endpoint failure stops matching플레이그라운드 열기 →
    1. import std.io
    2. function boom(divisor: int) -> int {
    3. io.writeLine("boom")
    4. 1 / divisor
    5. }
    6. let chosen = match (0) {
    7. case (0 .. boom(0)) => 7
    8. case _ => 9
    9. }
    10. io.writeLine("{chosen}")
    기대 출력0이 아닌 종료 코드
    boom
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 run. 종료 코드가 0이 아닙니다.

    필수 기본 위치 계약은 미정입니다.

    기대 표준 출력
    1. boom

    검토한 대안

    • 갈래의 끝값을 모두 미리 평가한다. 선택되지 않을 대안의 실패가 사용자가 고른 경로를 망가뜨립니다.
    • 상수 끝값만 받는다. 이미 쓰이는 계산된 범위까지 거절합니다.

    이유

    평가되는 식과 실패가 패턴을 시험하는 순서에서 직접 읽힙니다.

    바뀐 규칙 Integer range patterns →

    나머지를 받을 때도 하위 패턴을 씁니다

    2026년 11월 7일 채택 · 6.0.0 · 확인 중

    문제

    리스트 패턴에서 앞부분만 쓰고 나머지는 버릴 수 있습니다. .. 뒤에 아무것도 쓰지 않으면 버리는 자리와 빠뜨린 자리를 구분하기 어렵습니다.

    결정

    .. 뒤에는 항상 패턴을 씁니다. 나머지를 버리려면 .._를 씁니다.

    예제

    Rejecting a rest marker without a pattern

    example.tpzRejecting a rest marker without a pattern플레이그라운드 열기 →
    1. let count = match ([1, 2]) {
    2. case [..] => 2
    3. }
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    • TPZ2001 →

      list-rest-pattern-required at example.tpz:2:13

    Rejecting an omitted middle rest pattern

    example.tpzRejecting an omitted middle rest pattern플레이그라운드 열기 →
    1. let total = match ([1, 2, 3]) {
    2. case [first, .., last] => first + last
    3. case _ => 0
    4. }
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    • TPZ2001 →

      list-rest-pattern-required at example.tpz:2:20

    Ignoring a rest with an explicit wildcard

    example.tpzIgnoring a rest with an explicit wildcard플레이그라운드 열기 →
    1. import std.io
    2. let middle = match ([1, 2, 3, 4]) {
    3. case [first, .._, last] => "{first} {last}"
    4. case _ => "miss"
    5. }
    6. let leading = match ([1, 2, 3, 4]) {
    7. case [.._, last] => last
    8. case _ => 0
    9. }
    10. let trailing = match ([1, 2, 3, 4]) {
    11. case [first, .._] => first
    12. case _ => 0
    13. }
    14. let empty: Array<int> = []
    15. let ignored = match (empty) {
    16. case [.._] if (empty.length == 0) => true
    17. case _ => false
    18. }
    19. io.writeLine(middle)
    20. io.writeLine("{leading}")
    21. io.writeLine("{trailing}")
    22. io.writeLine("{ignored}")
    기대 출력종료 코드 0
    1 4
    4
    1
    true
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 1 4
    2. 4
    3. 1
    4. true

    검토한 대안

    • 맨 ..로만 나머지를 버리고 .._는 거절한다. 묶기(..rest)와 버리기(.._)가 같은 규칙 하나여야 합니다.
    • 맨 ..와 .._를 모두 허용한다. 나머지를 버리는 방법이 둘이 됩니다.

    이유

    ..rest와 .._가 같은 규칙을 따르며 이름을 읽으면 버리는 위치도 보입니다.

    바뀐 규칙 A single list rest and its surrounding elements →

    인수가 없는 생성자도 괄호를 씁니다

    2026년 11월 7일 채택 · 6.0.0 · 확인 중

    문제

    생성자가 값을 품는지에 따라 괄호가 달라지면 선언을 먼저 봐야 합니다. 패턴에서 이름만 보면 생성자인지 새 이름을 붙인 것인지도 불분명할 수 있습니다.

    결정

    • 값과 패턴 모두에서 None(), Empty(), Some(x)처럼 생성자에 괄호를 씁니다.
    • 생성자와 이름이 충돌하는 바인딩은 거절합니다.

    예제

    Constructor patterns keep parentheses at every arity

    example.tpzConstructor patterns keep parentheses at every arity플레이그라운드 열기 →
    1. import std.io
    2. enum Choice { Empty, Filled(int), Pair(int, int) }
    3. function read(value: Choice) -> int {
    4. match (value) {
    5. case Empty() => 0
    6. case Filled(number) => number
    7. case Pair(left, right) => left + right
    8. }
    9. }
    10. function nested(value: Option<Choice>) -> int {
    11. match (value) {
    12. case None() => -1
    13. case Some(Empty()) => 0
    14. case Some(Filled(number)) => number
    15. case Some(Pair(left, right)) => left + right
    16. }
    17. }
    18. io.writeLine("{read(Choice.Empty())}")
    19. io.writeLine("{read(Choice.Filled(7))}")
    20. io.writeLine("{read(Choice.Pair(2, 3))}")
    21. io.writeLine("{nested(None())}")
    22. io.writeLine("{nested(Some(Choice.Empty()))}")
    기대 출력종료 코드 0
    0
    7
    5
    -1
    0
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 0
    2. 7
    3. 5
    4. -1
    5. 0

    None needs parentheses in a constructor pattern

    example.tpzNone needs parentheses in a constructor pattern플레이그라운드 열기 →
    1. function read(value: Option<int>) -> int {
    2. match (value) {
    3. case Some(number) => number
    4. case None => 0
    5. }
    6. }
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    • TPZ2012 →

      pattern-reserved-none-binding at example.tpz:4:14

    None needs parentheses in a constructor value

    example.tpzNone needs parentheses in a constructor value플레이그라운드 열기 →
    1. let maybe: Option<int> = None
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    • TPZ2012 →

      pattern-reserved-none-binding at example.tpz:1:26

    Qualified constructor patterns are rejected

    example.tpzQualified constructor patterns are rejected플레이그라운드 열기 →
    1. enum Choice { Empty }
    2. let value: Choice = Choice.Empty()
    3. let result = match (value) {
    4. case Choice.Empty => 1
    5. }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    필수 기본 위치 계약은 미정입니다.

    A qualified nullary constructor keeps its parentheses

    example.tpzA qualified nullary constructor keeps its parentheses플레이그라운드 열기 →
    1. enum Choice { Empty }
    2. let value: Choice = Choice.Empty()
    기대 출력종료 코드 0
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    검사가 프로그램을 받아들입니다. 종료 코드 0.

    검토한 대안

    • 인수가 없는 생성자만 이름으로 쓴다. 선언과 쓰는 자리를 함께 봐야 같은 이름의 역할을 알 수 있습니다.
    • 두 철자를 모두 허용한다. 같은 생성자를 쓰는 방법이 둘이 됩니다.
    • 패턴에서만 괄호를 쓴다. 자리에 따라 같은 이름의 모양이 갈립니다.

    이유

    생성자 표기는 인수 개수와 쓰이는 위치에 관계없이 같습니다.

    바뀐 규칙 Constructor syntax and binding names →Variants without payloads →

    match는 가능한 값을 모두 다룹니다

    2026년 11월 9일 채택 · 6.0.0 · 구현 중

    문제

    정수나 문자열처럼 값이 열려 있는 타입을 match로 처리하면서 나머지 경우를 빠뜨리면, 검사는 통과하고 그 값이 실제로 들어올 때 실행이 멈췄습니다.

    결정

    • 모든 match는 검사 단계에서 가능한 값을 빠짐없이 다뤄야 합니다.
    • 열거형, Option, Result, bool, 닫힌 합집합은 모든 경우를 다룹니다. 생성자가 품은 값의 타입이 닫혀 있으면 그 안까지 따집니다.
    • 정수, 실수, 문자열, 배열, 범위, 타입 매개변수처럼 열린 타입에는 마지막에 조건 없는 갈래가 필요합니다.
    • 조건이 붙은 갈래는 덮음으로 세지 않습니다.
    • 빠진 경우는 검사 단계의 TPZ5021입니다. 실행 중 진단 TPZ4006은 6.0.0에서 쓰지 않습니다.

    예제

    Option bool covers both payloads and None

    example.tpzOption bool covers both payloads and None플레이그라운드 열기 →
    1. import std.io
    2. function read(value: Option<bool>) -> int {
    3. match (value) {
    4. case Some(true) => 1
    5. case Some(false) => 0
    6. case None() => -1
    7. }
    8. }
    9. let flags = map { "on": true, "off": false }
    10. io.writeLine("{read(flags.get("on"))}")
    11. io.writeLine("{read(flags.get("off"))}")
    12. io.writeLine("{read(flags.get("missing"))}")
    기대 출력종료 코드 0
    1
    0
    -1
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 1
    2. 0
    3. -1

    Cover all payloads of a constructor with two bool fields →

    검토한 대안

    • 닫힌 타입만 검사하고 열린 타입은 실행 중에 실패하게 둔다. 나머지 값을 빠뜨린 코드가 검사를 통과하고, 드문 입력이 들어올 때 멈춥니다.
    • bool만 규칙으로 정하고 다른 타입은 미정으로 둔다. 열거형과 합집합에 어떤 갈래가 필요한지 같은 기준으로 말할 수 없습니다.

    이유

    실행 중에 match가 실패하는 경우가 사라지고, 빠진 경우는 언제나 검사 단계에서 보입니다. 열린 타입을 다루는 match에는 남은 값을 모두 받는 마지막 무조건 갈래가 하나 필요합니다.

    바뀐 규칙 Every match is exhaustive →Reserved runtime code and current checking diagnostic →Non-exhaustive match →

    해결한 미정 항목 Complete exhaustiveness contract →

    반복은 효과를 실행하고 컴프리헨션은 값을 모읍니다

    2026년 11월 7일 채택 · 6.0.0 · 확인 중

    문제

    반복문의 결과를 변수에 받으면 배열을 모으는 동작으로 바뀔 수 있었습니다. 같은 반복을 다른 위치에 옮겼을 때 결과 타입이 달라졌습니다.

    결정

    • for는 모든 문맥에서 효과를 실행하고 ()를 돌려줍니다.
    • 결과를 배열로 모을 때는 컴프리헨션을 씁니다.

    예제

    For results stay unit in grouped and bound positions

    example.tpzFor results stay unit in grouped and bound positions
    1. import std.io
    2. function items(label: string) -> Array<int> {
    3. io.writeLine(label)
    4. [1, 2]
    5. }
    6. let bound = for item in (items("bound")) {
    7. io.writeLine("{item}")
    8. item * 2
    9. }
    10. let grouped = (for item in (items("grouped")) {
    11. io.writeLine("{item}")
    12. item * 3
    13. })
    14. let emptyItems: Array<int> = []
    15. let empty = for item in (emptyItems) { item }
    16. io.writeLine("{bound} {grouped} {empty}")
    기대 출력종료 코드 0
    bound
    1
    2
    grouped
    1
    2
    () () ()
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. bound
    2. 1
    3. 2
    4. grouped
    5. 1
    6. 2
    7. () () ()

    For cannot supply an array result

    example.tpzFor cannot supply an array result
    1. let values: Array<int> = for item in ([1, 2]) { item * 2 }
    기대 출력0이 아닌 종료 코드
    표준 출력 없음.
    $ topaz check example.tpz --language-version 6.0 --format json
    기대 결과

    기대 결과

    거절 단계 check. 종료 코드가 0이 아닙니다.

    • TPZ5001 →

      for-result-type-mismatch at example.tpz:1:26

    Collect values with an array comprehension

    example.tpzCollect values with an array comprehension플레이그라운드 열기 →
    1. import std.io
    2. let values: Array<int> = [for item in ([1, 2]) => item * 2]
    3. io.writeLine("{values[0]} {values[1]}")
    기대 출력종료 코드 0
    2 4
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. 2 4

    검토한 대안

    • 값이 필요한 위치의 for가 배열을 모으도록 둔다. 놓인 자리에 따라 같은 반복문이 다른 일을 합니다.

    이유

    수집하는 코드와 효과를 반복하는 코드를 소스에서 구별할 수 있습니다. 중간에 멈추며 모으는 일은 누적 변수와 break로 드러내 쓰고, 멈추지 않고 모으는 일은 컴프리헨션으로 씁니다.

    바뀐 규칙 Statement and value uses of for →

    defer 진단은 블록을 쓰라고 안내합니다

    2026년 11월 16일 채택 · 6.0.0 · 구현 중

    문제

    defer f()를 거절하면서 호출도 가능하다는 메시지가 나올 수 있었습니다. 진단을 그대로 따라도 코드를 고칠 수 없었습니다.

    결정

    • 구문 분석 단계의 TPZ2004는 defer에 블록이 필요하다고 말하고 본문 식의 시작을 가리킵니다.
    • 코드를 고치는 예는 진단 설명에 둡니다.

    예제

    Rejecting a deferred call without a block

    example.tpzRejecting a deferred call without a block플레이그라운드 열기 →
    1. import std.io
    2. function finish() -> () {
    3. defer io.writeLine("cleanup")
    4. }
    5. finish()
    기대 출력0이 아닌 종료 코드
    $ topaz check example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 parse. 종료 코드가 0이 아닙니다.

    검토한 대안

    • 블록이나 호출을 쓸 수 있다는 기존 문구를 유지한다. 진단이 이미 지운 형태를 사용자에게 다시 제시합니다.
    • 메시지 안에 고쳐 쓴 예까지 넣는다. 고치는 법은 진단 설명에 이미 있어 같은 안내가 두 자리에 생깁니다.

    이유

    오류를 읽고 지연할 코드를 블록으로 옮길 수 있습니다.

    바뀐 규칙 Registering a deferred block →

    나중에 실행할 코드는 defer 블록에 넣습니다

    2026년 11월 7일 채택 · 6.0.0 · 확인 중

    문제

    지연 실행을 블록으로 쓰거나 호출 하나로 쓸 수 있었습니다. 같은 일을 다른 문법으로 적어야 하는 경우가 있었습니다.

    결정

    defer 뒤에는 블록을 씁니다. defer f() 같은 호출 형태는 구문 분석에서 거절합니다.

    예제

    Rejecting a deferred call without a block →

    Running a deferred block at scope exit

    example.tpzRunning a deferred block at scope exit플레이그라운드 열기 →
    1. import std.io
    2. function finish() -> () {
    3. defer { io.writeLine("cleanup") }
    4. io.writeLine("body")
    5. }
    6. finish()
    기대 출력종료 코드 0
    body
    cleanup
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. body
    2. cleanup

    검토한 대안

    • 블록과 호출 형태를 함께 유지한다. 같은 지연 실행을 적는 문법이 둘 남습니다.

    이유

    지연되는 코드의 시작과 끝이 블록에서 보입니다. 호출 형태는 인수를 등록할 때 평가해 정리할 때의 값과 어긋납니다. 지금 값을 붙잡으려면 let으로 드러내 씁니다.

    바뀐 규칙 Registering a deferred block →

    제어 이동은 defer 본문 경계를 넘을 수 없습니다

    2026년 11월 19일 채택 · 6.0.0 · 확인 중

    문제

    정리 안에서 바깥 함수로 반환하면 이미 진행 중인 반환과 부딪힙니다. 이전에는 이런 코드가 검사를 통과해 실행 중에야 오류를 출력할 수 있었습니다.

    결정

    • return, break, continue, ?가 defer 본문을 넘어가면 도달 가능성과 상관없이 해당 식에 검사 단계 TPZ5001을 냅니다.
    • 정리 안에서 정의한 함수나 람다의 반환과 전파, 정리 안에서 시작한 반복문의 이동은 해당 경계를 벗어나지 않는 한 허용합니다.
    • 중첩 정리에서는 각각의 defer 본문 경계를 적용합니다.

    검토한 대안

    • 정리 중 제어 이동에 우선순위를 준다. 이미 진행 중인 반환이나 정리를 바꾸거나 가릴 수 있습니다.

    이유

    잘못된 제어 이동을 실행 전에 찾고 정리 코드가 함수의 결과를 바꾸지 않도록 합니다.

    바뀐 규칙 Cleanup order on normal completion and control transfer →Runtime faults skip remaining cleanup →

    오류값을 반환하며 나갈 때도 등록한 정리를 실행합니다

    2026년 11월 7일 채택 · 6.0.0 · 확인 중

    문제

    함수에서 ?로 Err를 돌려보낼 때 블록 끝에 닿지 않습니다. 그 전에 등록한 정리가 어느 순서로 실행될지 알아야 합니다.

    결정

    • ?가 Err를 돌려주며 벗어나는 범위의 defer는 등록한 역순으로 실행합니다. Ok에서는 범위를 벗어나지 않습니다.
    • using이 맡는 자동 닫기도 같은 종료 규칙을 따릅니다.

    예제

    Cleaning up scopes during error propagation

    example.tpzCleaning up scopes during error propagation플레이그라운드 열기 →
    1. import std.io
    2. function fail() -> Result<int, string> {
    3. io.writeLine("operand")
    4. Err("stop")
    5. }
    6. function finish() -> Result<int, string> {
    7. defer { io.writeLine("outer") }
    8. let value = {
    9. defer { io.writeLine("inner-first") }
    10. defer { io.writeLine("inner-second") }
    11. fail()?
    12. }
    13. io.writeLine("unreachable")
    14. Ok(value)
    15. }
    16. io.writeLine(match (finish()) {
    17. case Ok(value) => "value={value}"
    18. case Err(error) => error
    19. })
    기대 출력종료 코드 0
    operand
    inner-second
    inner-first
    outer
    stop
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    실행을 마칩니다. 종료 코드 0.

    기대 표준 출력
    1. operand
    2. inner-second
    3. inner-first
    4. outer
    5. stop

    검토한 대안

    • ?가 오류를 돌려줄 때 defer를 건너뛴다. 조기 반환과 정상 끝에서 등록한 정리의 의미가 달라집니다.
    • using만 특례로 정리한다. 스코프를 벗어나는 방법과 상관없이 정리 규칙이 하나여야 합니다.

    이유

    정리해야 할 일을 같은 범위에 등록하면 구조화된 출구에 공통으로 적용됩니다.

    바뀐 규칙 Cleanup order on normal completion and control transfer →Using acquisition and cleanup order →

    복구할 수 없는 실행 오류가 나면 남은 정리는 실행하지 않습니다

    2026년 11월 9일 채택 · 6.0.0 · 확인 중

    문제

    실행 오류로 프로그램이 끝날 때 등록한 정리가 남아 있을 수 있습니다. 정리 블록도 출력을 하거나 또 실패할 수 있습니다.

    결정

    일반 실행 오류는 잡아서 계속할 수 없는 종료입니다. 남은 defer 블록과 using 정리를 실행하지 않습니다.

    예제

    A runtime fault leaves defer output absent

    example.tpzA runtime fault leaves defer output absent플레이그라운드 열기 →
    1. import std.io
    2. function divide(divisor: int) -> int {
    3. defer { io.writeLine("cleanup") }
    4. io.writeLine("before fault")
    5. 12 / divisor
    6. }
    7. io.writeLine("{divide(0)}")
    기대 출력0이 아닌 종료 코드
    before fault
    
    $ topaz run example.tpz --language-version 6.0
    기대 결과

    기대 결과

    거절 단계 run. 종료 코드가 0이 아닙니다.

    기대 표준 출력
    1. before fault

    검토한 대안

    • 실행 오류 뒤에도 남은 정리를 실행한다. 첫 오류 뒤에 새로운 출력이나 두 번째 오류가 이어질 수 있습니다.
    • fault 때 정리를 "보장 없음"으로 둔다. 같은 프로그램의 출력이 재현되도록 동작을 하나로 정해야 합니다.

    이유

    실행이 어느 오류에서 멈추는지 알 수 있습니다.

    바뀐 규칙 Runtime faults skip remaining cleanup →

    일부 답한 미정 항목 Pending: complete defer contexts and abrupt exits →

    판 이력