std.path | Topaz

이름	모듈
Path.extension →	std.path →
Path.fileName →	std.path →
Path.from →	std.path →
Path.join →	std.path →
Path.parent →	std.path →
Path.toString →	std.path →
Path.withExtension →	std.path →

Module

The module exports immutable normalized relative paths. Path.from constructs a path from text. Members inspect components or produce another normalized Path without accessing the filesystem.

Why

링크

A normalized representation gives path composition one meaning before the host applies filesystem permissions and platform rules.

Availability

링크

Import std.path in language mode 5.21. The current compiler selects std/path.tpz for this language mode. Availability in other released editions and inclusion in each installed distribution are Pending.

Exported types

링크

export type Path = Path

Type members keep the compiler-owned type name shown in their declarations. Importing a module does not create a new type identity.

Public API

Pending contracts

링크

Construct normalized paths with Path.from

링크

규칙topaz.stdlib.contract.path-from.rule

Construct normalized paths with Path.from

Path.from(text) is the constructor for normalized relative paths and returns Result<Path, string>.

Path.from normalizes path separators and removes empty and dot components. Parent components must stay within the relative root. A path reduced to no components is represented by a dot.

Empty text, NUL, absolute paths, and parent traversal beyond the relative root return Err. These input failures are values that a caller can handle.

A leading slash or backslash returns Err. Text that starts with one ASCII character followed immediately by a colon returns Err.

Path.cwdRelative and Path.project are absent. A Path value already satisfies normalization and has no normalize member.

Path operations inspect text without accessing the filesystem. Constructing a Path does not establish that its target exists or is accessible.

이유

One constructor gives relative path text one interpretation. Normalization is a Path invariant, so a separate identity operation gives the same value a second spelling.

예제 Construct a normalized path →Reject a path that escapes its relative root →Reject Path.cwdRelative →Reject Path.project →Reject Path.normalize →Distinguish rejected ASCII prefixes from relative path text →

진단 TPZ5006 →

Construct a normalized path

링크

run · running · 검증 · 미실행

main.tpzConstruct a normalized path플레이그라운드 열기 →

import std.path { Path }
import std.test
import std.io
let chapter = test.assertOk(Path.from("chapters/./draft/../main.tpz"))
io.writeLine(chapter.toString())

기대 출력종료 코드 0

chapters/main.tpz

$ topaz run main.tpz · 대상 제품 5.21.3

기대 결과

실행을 마칩니다. 종료 코드 0.

표준 오류 출력 없음.

기대 표준 출력

chapters/main.tpz

이 예제는 아직 실행하지 않았습니다.

Reject a path that escapes its relative root

링크

run · running · 검증 · 미실행

main.tpzReject a path that escapes its relative root플레이그라운드 열기 →

import std.path { Path }
import std.io
match (Path.from("../chapter.tpz")) {
case Err(_) => io.writeLine("outside root rejected")
case Ok(_) => io.writeLine("accepted")
}

기대 출력종료 코드 0

outside root rejected

$ topaz run main.tpz · 대상 제품 5.21.3

기대 결과

실행을 마칩니다. 종료 코드 0.

표준 오류 출력 없음.

기대 표준 출력

outside root rejected

이 예제는 아직 실행하지 않았습니다.

Reject Path.cwdRelative

링크

reject · checking · 검증 · 미실행

main.tpzReject Path.cwdRelative플레이그라운드 열기 →

import std.path { Path }
let value = Path.cwdRelative("chapter.tpz")

기대 출력0이 아닌 종료 코드

표준 출력 없음.

$ topaz check main.tpz --format json · 대상 제품 5.21.3

기대 결과

거절 단계 check. 종료 코드가 0이 아닙니다.

TPZ5006 →
stdlib-removed-member at main.tpz:2:18

표준 출력 없음.

이 예제는 아직 실행하지 않았습니다.

Reject Path.project

링크

reject · checking · 검증 · 미실행

main.tpzReject Path.project플레이그라운드 열기 →

import std.path { Path }
let value = Path.project("chapter.tpz")

기대 출력0이 아닌 종료 코드

표준 출력 없음.

$ topaz check main.tpz --format json · 대상 제품 5.21.3

기대 결과

거절 단계 check. 종료 코드가 0이 아닙니다.

TPZ5006 →
stdlib-removed-member at main.tpz:2:18

표준 출력 없음.

이 예제는 아직 실행하지 않았습니다.

Reject Path.normalize

링크

reject · checking · 검증 · 미실행

main.tpzReject Path.normalize플레이그라운드 열기 →

import std.path { Path }
function inspect(path: Path) -> () {
let value = path.normalize()
return ()
}

기대 출력0이 아닌 종료 코드

표준 출력 없음.

$ topaz check main.tpz --format json · 대상 제품 5.21.3

기대 결과

거절 단계 check. 종료 코드가 0이 아닙니다.

TPZ5006 →
stdlib-removed-member at main.tpz:3:20

표준 출력 없음.

이 예제는 아직 실행하지 않았습니다.

Distinguish rejected ASCII prefixes from relative path text

링크

run · running · 검증 · 미실행

main.tpzDistinguish rejected ASCII prefixes from relative path text플레이그라운드 열기 →

import std.path { Path }
import std.test
import std.io
test.assertErr(Path.from("a:"))
test.assertErr(Path.from("1:"))
test.assertErr(Path.from("!:"))
io.writeLine(test.assertOk(Path.from("aa:")).toString())
io.writeLine(test.assertOk(Path.from("é:")).toString())
io.writeLine(test.assertOk(Path.from("가:")).toString())

기대 출력종료 코드 0

aa:
é:
가:

$ topaz run main.tpz · 대상 제품 5.21.3

기대 결과

실행을 마칩니다. 종료 코드 0.

표준 오류 출력 없음.

기대 표준 출력

aa:
é:
가:

이 예제는 아직 실행하지 않았습니다.

Diagnostics

링크

Unknown member or field →

Inspect and transform normalized paths

링크

규칙topaz.stdlib.contract.path-operations.rule

Inspect and transform normalized paths

A Path is immutable normalized relative text. Every member evaluates its receiver and arguments once in ordinary call order. Members perform no host access and leave the receiver unchanged on success and failure.

toString returns the exact normalized representation. Separators are forward slashes and the relative root is a dot. Constructing a Path from that text returns the same representation.

join accepts nonempty relative child text. It rejects NUL, a leading separator, and a colon immediately after one ASCII character before combining the child with the receiver. Both slash forms are separators. Parent components remove preceding components from the combined path and return Err when none remain to remove.

Joining a child may reach the relative root but may not cross it. A dot child preserves the receiver. Invalid child text returns Err containing an error string without producing a Path. Error text identifies Path.join and the invalid condition.

parent removes the final component. For a one component path it returns Some containing the dot root. The relative root has no parent and returns None().

fileName returns the final component without any preceding separator. The relative root returns None(). These results describe text and do not establish whether the path identifies a file or directory.

extension returns the text after the final dot in the file name, provided that dot is not its first character. A leading dot alone does not introduce an extension. A final dot returns Some(""). A name without such a dot and the relative root return None().

withExtension replaces the final extension or appends one when it is absent. The argument supplies the suffix without a leading dot. An empty argument removes an existing suffix and its separating dot. A leading dot, either separator, or NUL in the argument returns Err.

withExtension preserves a leading dot that belongs to the file name. It returns Err when the receiver is the relative root because that path has no file name. A successful replacement is normalized with the same rules as Path.from.

Path validation describes lexical text. Host operations may reject an otherwise valid Path because of platform naming rules, permissions, or capability restrictions. A Path does not establish filesystem existence or prevent a symbolic link from resolving elsewhere.

이유

One normalized representation makes composition predictable. Parent and extension queries describe components without consulting host state. A suffix has one accepted spelling, and joining validates the child before its leading separator can disappear inside the combined text.

예제 Join relative components without changing the receiver →Reject invalid child text before joining →Inspect the final component and the relative root →Keep the relative root as the parent of one component →Distinguish an absent extension from an empty extension →Replace and remove a final extension →Preserve the name of a file that starts with a dot →Reject a second suffix spelling and a path without a file name →

Join relative components without changing the receiver

링크

run · running · 검증 · 미실행

main.tpzJoin relative components without changing the receiver플레이그라운드 열기 →

import std.path { Path }
import std.test
import std.io
let base = test.assertOk(Path.from("chapters/draft"))
let child = test.assertOk(base.join("../final/./main.tpz"))
io.writeLine(base.toString())
io.writeLine(child.toString())
io.writeLine(test.assertOk(base.join("../..")).toString())
io.writeLine(test.assertOk(base.join(".")).toString())

기대 출력종료 코드 0

chapters/draft
chapters/final/main.tpz
.
chapters/draft

$ topaz run main.tpz · 대상 제품 5.21.3

기대 결과

실행을 마칩니다. 종료 코드 0.

표준 오류 출력 없음.

기대 표준 출력

chapters/draft
chapters/final/main.tpz
.
chapters/draft

이 예제는 아직 실행하지 않았습니다.

Reject invalid child text before joining

링크

run · running · 검증 · 미실행

main.tpzReject invalid child text before joining플레이그라운드 열기 →

import std.path { Path }
import std.test
import std.io
let base = test.assertOk(Path.from("chapters"))
for child in (["", "/outside", "C:/outside", "../../outside"]) {
match (base.join(child)) {
case Err(_) => io.writeLine("rejected")
case Ok(_) => io.writeLine("accepted")
}
}
io.writeLine(base.toString())

기대 출력종료 코드 0

rejected
rejected
rejected
rejected
chapters

$ topaz run main.tpz · 대상 제품 5.21.3

기대 결과

실행을 마칩니다. 종료 코드 0.

표준 오류 출력 없음.

기대 표준 출력

rejected
rejected
rejected
rejected
chapters

이 예제는 아직 실행하지 않았습니다.

Inspect the final component and the relative root

링크

run · running · 검증 · 미실행

main.tpzInspect the final component and the relative root플레이그라운드 열기 →

import std.path { Path }
import std.test
import std.io
let file = test.assertOk(Path.from("chapters/main.tpz"))
io.writeLine(test.assertSome(file.parent()).toString())
io.writeLine(test.assertSome(file.fileName()))
io.writeLine(test.assertSome(file.extension()))
let root = test.assertOk(Path.from("."))
test.assertNone(root.parent())
test.assertNone(root.fileName())
test.assertNone(root.extension())
io.writeLine(root.toString())

기대 출력종료 코드 0

chapters
main.tpz
tpz
.

$ topaz run main.tpz · 대상 제품 5.21.3

기대 결과

실행을 마칩니다. 종료 코드 0.

표준 오류 출력 없음.

기대 표준 출력

chapters
main.tpz
tpz
.

이 예제는 아직 실행하지 않았습니다.

Keep the relative root as the parent of one component

링크

run · running · 검증 · 미실행

main.tpzKeep the relative root as the parent of one component플레이그라운드 열기 →

import std.path { Path }
import std.test
import std.io
let file = test.assertOk(Path.from("main.tpz"))
match (file.parent()) {
case Some(parent) => io.writeLine(parent.toString())
case None() => io.writeLine("missing")
}

기대 출력종료 코드 0

$ topaz run main.tpz · 대상 제품 5.21.3

기대 결과

실행을 마칩니다. 종료 코드 0.

표준 오류 출력 없음.

기대 표준 출력

.

이 예제는 아직 실행하지 않았습니다.

Distinguish an absent extension from an empty extension

링크

run · running · 검증 · 미실행

main.tpzDistinguish an absent extension from an empty extension플레이그라운드 열기 →

import std.path { Path }
import std.test
import std.io
for name in (["README", ".env", ".env.local", "archive.tar.gz", "trailing."]) {
let file = test.assertOk(Path.from(name))
match (file.extension()) {
case Some(extension) => io.writeLine("present [{extension}]")
case None() => io.writeLine("absent")
}
}

기대 출력종료 코드 0

absent
absent
present [local]
present [gz]
present []

$ topaz run main.tpz · 대상 제품 5.21.3

기대 결과

실행을 마칩니다. 종료 코드 0.

표준 오류 출력 없음.

기대 표준 출력

absent
absent
present [local]
present [gz]
present []

이 예제는 아직 실행하지 않았습니다.

Replace and remove a final extension

링크

run · running · 검증 · 미실행

main.tpzReplace and remove a final extension플레이그라운드 열기 →

import std.path { Path }
import std.test
import std.io
let file = test.assertOk(Path.from("chapters/main.tpz"))
io.writeLine(test.assertOk(file.withExtension("pdf")).toString())
io.writeLine(test.assertOk(file.withExtension("")).toString())
io.writeLine(file.toString())

기대 출력종료 코드 0

chapters/main.pdf
chapters/main
chapters/main.tpz

$ topaz run main.tpz · 대상 제품 5.21.3

기대 결과

실행을 마칩니다. 종료 코드 0.

표준 오류 출력 없음.

기대 표준 출력

chapters/main.pdf
chapters/main
chapters/main.tpz

이 예제는 아직 실행하지 않았습니다.

Preserve the name of a file that starts with a dot

링크

run · running · 검증 · 미실행

main.tpzPreserve the name of a file that starts with a dot플레이그라운드 열기 →

import std.path { Path }
import std.test
import std.io
let file = test.assertOk(Path.from(".env"))
io.writeLine(test.assertOk(file.withExtension("local")).toString())
io.writeLine(test.assertOk(file.withExtension("")).toString())

기대 출력종료 코드 0

.env.local
.env

$ topaz run main.tpz · 대상 제품 5.21.3

기대 결과

실행을 마칩니다. 종료 코드 0.

표준 오류 출력 없음.

기대 표준 출력

.env.local
.env

이 예제는 아직 실행하지 않았습니다.

Reject a second suffix spelling and a path without a file name

링크

run · running · 검증 · 미실행

main.tpzReject a second suffix spelling and a path without a file name플레이그라운드 열기 →

import std.path { Path }
import std.test
import std.io
let file = test.assertOk(Path.from("chapter.txt"))
for extension in ([".pdf", "pdf/extra", "pdf\\extra"]) {
match (file.withExtension(extension)) {
case Err(_) => io.writeLine("rejected")
case Ok(_) => io.writeLine("accepted")
}
}
let root = test.assertOk(Path.from("."))
match (root.withExtension("pdf")) {
case Err(_) => io.writeLine("root rejected")
case Ok(_) => io.writeLine("root accepted")
}

기대 출력종료 코드 0

rejected
rejected
rejected
root rejected

$ topaz run main.tpz · 대상 제품 5.21.3

기대 결과

실행을 마칩니다. 종료 코드 0.

표준 오류 출력 없음.

기대 표준 출력

rejected
rejected
rejected
root rejected

이 예제는 아직 실행하지 않았습니다.

이 모듈의 API

Module

Why

Availability

Exported types

Public API

Pending contracts

Construct normalized paths with Path.from

Construct normalized paths with Path.from

이유

Construct a normalized path

기대 결과

Reject a path that escapes its relative root

기대 결과

Reject Path.cwdRelative

기대 결과

Reject Path.project

기대 결과

Reject Path.normalize

기대 결과

Distinguish rejected ASCII prefixes from relative path text

기대 결과

Diagnostics

Inspect and transform normalized paths

Inspect and transform normalized paths

이유

Join relative components without changing the receiver

기대 결과

Reject invalid child text before joining

기대 결과

Inspect the final component and the relative root

기대 결과

Keep the relative root as the parent of one component

기대 결과

Distinguish an absent extension from an empty extension

기대 결과

Replace and remove a final extension

기대 결과

Preserve the name of a file that starts with a dot

기대 결과

Reject a second suffix spelling and a path without a file name

기대 결과